转区的货币需要自已修改脚本,默认是用的金币
[@main]
#IF
#ACT
CloseBigDialogBox
MOV S$转区金额
MOV S$转区数据
MOV S$转区密码
MOV S$显示金额1 <$goldcount>
MOV S$显示金额2 0
MOV S38
MOV S44
MOV N24 0
GOTO @显示转区
break
[@显示转区]
#if
CHECKTEXTLIST ..\..\..\..\通区文本\转区数据.txt [<$USERID>]
#act
GetStringPos ..\..\..\..\通区文本\转区数据.txt [<$USERID>]
INC N0 1
GetListString ..\..\..\..\通区文本\转区数据.txt <$STR(N0)> S$转区数据
EXTRACTSTRING ; <$STR(S$转区数据)> S$转区密码 S$转区金额 S$转区玩家名 S$来源区 S$转区时间
MOV S$显示金额2 <$STR(S$转区金额)>
#if
#act
SetStringBlank <$STR(S$显示金额1)> 25 1
#SAY
\ \ \
\<转区只需扣除5%的手续费，例：转19扣除1金币，转21扣除2金币！/FCOLOR=250>\
\<请认真填写转区密码建议6-10位字母+数字，复杂些！如遗忘，概不负责/AUTOCOLOR=254,251,168,191,250,70,245,249,253>\
\<目标区必须与本区账号相同的账号！转完之后立刻领取！合区之后概不负责/AUTOCOLOR=254,251,168,191,250,70,245,249,253>\
\<当前金币数额:/FCOLOR=250>{<$STR(S$显示金额1)>/FCOLOR=250} <可领取转区金币数:>{<$STR(S$显示金额2)>/FCOLOR=70}\ \
\<请填写需要转区的金额:/@@InPutInteger24> <$STR(N24)> <确认资料,开始转区/@确认转区>\ \
\<请填写转区密码:|250#此密码为自定义数字,作为转区凭证/@@InPutString38(此密码为自定义数字,作为转区凭证)> <领取转区/@领取转区>\ \
\ \ \
\
[@InPutInteger24]
#if
CheckContainsText <$SERVERNAME> 测试
#act
MESSAGEBOX 当前是测试模式,不能进行金币转区!
break
#IF
SMALL N24 10
#ACT
MESSAGEBOX 请输入大于10的金额!
BREAK
#IF
LARGE N24 1000
#ACT
MESSAGEBOX 请输入不大于1000的金额!
BREAK
#IF
checkgold <$STR(N24)>
#ACT
GOTO @显示转区
BREAK
#ELSEACT
MOV N24 0
MESSAGEBOX 你没有这么多金币!
GOTO @显示转区
BREAK
[@InPutString38]
#if
CheckContainsText <$SERVERNAME> 测试
#act
MESSAGEBOX 当前是测试模式,不能进行金币转区!
break
#IF
CheckStringlength <$STR(S38)> > 0
#ACT
BREAK
#say
\ \ \
\ <转区需要扣除5%手续费,请认真填写转区密码,如密码遗忘导致无法领取,概不负责找回!/FCOLOR=250>\ \
\ <请再次确认转区密码:|250#此密码为自定义数字,作为转区凭证/@@InPutString44(此密码为自定义数字,作为转区凭证)>
#ELSEACT
MOV S38
MESSAGEBOX 输入错误!
GOTO @显示转区
BREAK
[@InPutString44]
#IF
CheckStringlength <$STR(S44)> > 0
#ACT
#ELSEACT
MOV S44
MESSAGEBOX 输入错误!
break
#if
EQUAL S44 <$STR(S38)>
#act
MESSAGEBOX 设置成功,请牢记转区密码:<$STR(S44)>,以免影响提取!
GOTO @显示转区
break
#elseact
MOV S44
MESSAGEBOX 两次密码输入不一致,请重新输入!
break
[@领取转区]
#if
CheckContainsText <$SERVERNAME> 测试
#act
MESSAGEBOX 当前是测试模式,不能提取转区金币!
break
#if
CHECKTEXTLIST ..\..\..\..\通区文本\转区数据.txt [<$USERID>]
#act
GetStringPos ..\..\..\..\通区文本\转区数据.txt [<$USERID>]
INC N0 1
GetListString ..\..\..\..\通区文本\转区数据.txt <$STR(N0)> S$转区数据
EXTRACTSTRING ; <$STR(S$转区数据)> S$转区密码 S$转区金额 S$转区玩家名 S$来源区 S$转区时间
DEC S$转区密码 转区密码:
DEC S$转区金额 转区金额:
MOV S$显示金额2 <$STR(S$转区金额)>
#ELSEACT
MESSAGEBOX 你并没有转区充值可领取!
BREAK
#if
#act
SetStringBlank <$STR(S$显示金额1)> 25 0
break
#SAY
\ \ \
\ <当前金币数额:/FCOLOR=250>{<$STR(S$显示金额1)>/FCOLOR=250}<可领取转区金币数:>{<$STR(S$显示金额2)>/FCOLOR=70}\ \
\ <转区需要扣除5%手续费,请认真填写转区密码,如密码遗忘导致无法领取,概不负责找回!/FCOLOR=250>\ \
\ <输入转区密码:/@@InPutString50(输入转区时设置的密码:)>\
[@InPutString50]
#if
EQUAL S50 <$STR(S$转区密码)>
#act
MOV N$转区检测 1
GOTO @提取转区
break
#elseact
MESSAGEBOX 密码错误,请重新输入!
break
[@提取转区]
#if
EQUAL N$转区检测 1
#act
#elseact
break
#IF
CHECKTEXTLIST ..\..\..\..\通区文本\转区数据.txt [<$USERID>]
#ACT
GetStringPos ..\..\..\..\通区文本\转区数据.txt [<$USERID>]
INC N0 1
GetListString ..\..\..\..\通区文本\转区数据.txt <$STR(N0)> S$读取转区
EXTRACTSTRING ; <$STR(S$读取转区)> S$转区密码 S$转区金额 S$转区玩家名 S$来源区 S$转区时间
DEC S$转区密码 转区密码:
DEC S$转区金额 转区金额:
MOV N$读取金额 <$STR(S$转区金额)>
#ELSEACT
MOV N$转区检测 0
MESSAGEBOX 你并没有转区充值可领取!
BREAK
#IF
LARGE N$读取金额 0
#ACT
GAMEDIAMOND + <$STR(N$读取金额)>
DelTextList ..\..\..\..\通区文本\转区数据.txt [<$USERID>]
DelTextList ..\..\..\..\通区文本\转区数据.txt <$STR(S$读取转区)>
MOV N$读取金额 0
MOV N$转区检测 0
MOV S$读取转区
MESSAGEBOX 恭喜你成功领取转区金币!
GOTO @main
BREAK
#ELSEACT
MOV N$转区检测 0
MESSAGEBOX 未知错误,请联系GM!
BREAK
[@确认转区]
#if
CheckContainsText <$SERVERNAME> 测试
#act
MESSAGEBOX 当前是测试模式,不能进行金币转区!
break
#IF
SMALL N24 10
#ACT
MESSAGEBOX 请输入大于10的金额!
BREAK
#IF
LARGE N24 1000
#ACT
MESSAGEBOX 请输入不大于1000的金额!
BREAK
#OR
EQUAL S38
EQUAL S44
#ACT
MESSAGEBOX 请设置转区密码!
BREAK
#IF
checkgold <$STR(N24)>
#ACT
#ELSEACT
MESSAGEBOX 你没有这么多金币可以转!
BREAK
#IF
NOT CHECKTEXTLIST ..\..\..\..\通区文本\转区数据.txt [<$USERID>]
#ACT
Take 金币 <$STR(N24)>
MOV N$记录金额 <$STR(N24)>
MUL N$记录金额 95
DIV N$记录金额 100
MOV S$记录转区 转区密码:<$STR(S44)>
INC S$记录转区 ;转区金额:<$STR(N$记录金额)>
INC S$记录转区 ;玩家名称:<$USERNAME>
INC S$记录转区 ;来源区:<$SERVERNAME>
INC S$记录转区 ;提现时间:<$YEAR>年<$MONTH>月<$DAY>日,<$HOUR>:<$MINUTE>:<$SECOND>
AddTextList ..\..\..\..\通区文本\转区数据.txt [<$USERID>]
GetStringPos ..\..\..\..\通区文本\转区数据.txt [<$USERID>]
INC N0 1
AddTextListEx ..\..\..\..\通区文本\转区数据.txt <$STR(S$记录转区)> <$STR(N0)>
MOV N24 0
MOV S38
MOV S44
MESSAGEBOX 金币转区成功!
SuperMoveMsg 0 251 0 18 140 2 {【系统】:|58:0:1}恭喜玩家{[<$USERNAME>]|254:0:1}成功将{[<$STR(N$记录金额)>]|239:0:1}金币进行转区!!!
GOTO @main
BREAK
#ELSEACT
MESSAGEBOX 当前帐号已有转区记录,请先领取过之后再来申请!
GOTO @main
BREAK
